pedido de macro

[Sa1tama_]

Alguém tem uma macro que repara picareta automaticamente quando chega á uma certa durabilidade?

 

[lomexicano]

Alguém tem uma macro que repara picareta automaticamente quando chega á uma certa durabilidade?

para 1.5 ou 1.8?

 

[GengisKhanBr]

Tb to precisando

 

[Black Fox]

Caso esteja com algum problema me avise.

$${
toggle(repair)
if(repair)
log("&f[Info] &5Proteção a &6Picareta &aIniciado")
do
if((DURABILITY <= 30) && (ITEM == "diamond_pickaxe"))
}$$/reparar$${
endif
loop
else
log("&f[Info] &5Proteção a &6Picareta &cDesligado")
stop
endif
}$$

Macro feita pelo @lomexicano

 

[lomexicano]

fiz uma macrinho aqui agora (tem um projeto de auto-click incluso, no qual ele alterna entre picareta e pá, dependendo de o que está na mira, se você ativar (clicando CTRL) --> isso não é obrigatório, você pode só usar o auto-rep mesmo )

$${
&ids = "diamond_pickaxe|diamond_axe|diamond_shovel|^277$|^278$|^279$";
#durabilidade = 100;

ifmatches(%ITEM%,"[a-zA-Z]"); set(&version,"1.8"); else; set(&version,"1.5"); endif;

&ids_terra = "dirt|grass|^sand$|gravel|^13$|^12$|^2$|^3$|snow_layer|^78$";
&ids_pedra = "stone|^1$|cobblestone|^4$|ore|^129$|monster_egg|^97$|^79$|^ice$";

log(" ");
toggle(a); if(!a); log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &f&lAuto&7[&f&lRep&7+&6&lClick&7] &c&lOFF&f&l!"); stop; endif; log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &f&lAuto&7[&f&lRep&7+&6&lClick&7] &a&lON&f&l!");
unset(autoclick);
log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &7pressione &6CTRL&f para ativar o &6auto-click");

do();
    if(CTRL); 
        toggle(autoclick);
        if(autoclick); 
            log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &6Autoclick &aativado&f! &7(versao %&version%)");
        else;
            log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &6Autoclick &cdesativado&f! &7(versao %&version%)");
        endif;
        do(); 
            wait(10ms); 
        until(!CTRL); 
    endif;
    ifmatches(%ITEM%,%&ids%);
        if(%DURABILITY% < %#durabilidade%);
            log(" "); log(" "); log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &f&4Durabilidade&f&l!!!");
            echo("/reparar");
            wait(2000ms);
        endif;
    endif;
   
    if(autoclick);
        do();
            if(CTRL); break; endif;
            unsafe(0);
                ifmatches(%HITID%,%&ids_terra%);
                    ifmatches(%&version%,"1.8");
                        pick(diamond_shovel,iron_shovel,stone_shovel,wooden_shovel);
                    else;
                        pick(277,256,273,269);
                    endif;
                endif;
                ifmatches(%HITID%,%&ids_pedra%);
                    ifmatches(%&version%,"1.8");
                        pick(diamond_pickaxe,iron_pickaxe,stone_pickaxe,wooden_pickaxe);
                    else;
                        pick(278,257,274,270);
                    endif;
                endif;
            endunsafe;
            ifmatches(%HITID%,"%&ids_pedra%|%&ids_terra%");
                unsafe(0);
                    ifmatches(%HITID%,"%&ids_pedra%|%&ids_terra%");
                    else;
                        break;
                    endif;
                    if(CTRL); break; endif;
                endunsafe;
                ifmatches(%ITEM%,%&ids%);
                    if(%DURABILITY% >= %#durabilidade%);
                        key(attack);
                    else;
                        break;
                    endif;
                else;
                    break;
                endif;
            else;
                break;
            endif;
        loop;
    endif;
loop;
}$$

 

[Sa1tama_]

para 1.5 ou 1.8?

prá 1.8

 

[lomexicano]

prá 1.8

A que eu mandei ali deve funcionar sem problemas

 

[Sa1tama_]

A que eu mandei ali deve funcionar sem problemas

funcionou so que tem como tirar esse auto click? pq quandoeu uso o /bau vip ele fica iniciando sozinho!

 

[lomexicano]

Então isto aqui deve bastar. Lembrando que este tipo de macro não precisa de arquivo, apenas colar ele (em vez de digitar $$<arquivo.txt>) funcionaria sem problemas.

$${
&ids = "diamond_pickaxe|diamond_axe|diamond_shovel|^277$|^278$|^279$";
#durabilidade = 100;

log(" ");
toggle(a); if(!a); log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &f&lAuto&f&lRep &c&lOFF&f&l!"); stop; endif;
log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &f&lAuto&f&lRep  &a&lON&f&l!");

do();
    ifmatches(%ITEM%,%&ids%);
        if(%DURABILITY% < %#durabilidade%);
            log(" "); log(" "); log("&e&l[&2&lMA&f&lC&4&lRO&e&l]&r &f&4Durabilidade&f&l!!!");
            echo("/reparar");
            wait(2000ms);
        endif;
    endif;
    wait(500ms);
loop;
}$$